Medieval Manuscript Data Integration Ontology (MMDIO)

Abstract

Introduction

MMDIO, an OWL 2 DL ontology, provides a detailed structure to represent medieval manuscript information from diverse sources.It is built on the Memo ontology and uses the FRBR-aligned Bibliographic Ontology(FaBiO) approach to distinguish between intellectual content (Expressions) and physical forms (Manifestations). MMDIO advances this method to create a more flexible, adaptable, and interoperable system for manuscript data. By incorporating features that capture both the intellectual and physical characteristics of manuscripts, MMDIO supports a wide range of scholarly activities, from in-depth manuscript analysis to comprehensive historical research.

The objectives of MMDIO are diverse and aim to:

• Facilitate seamless integration and interaction between the Mosaico and Irnerio platforms, ensuring unified access to medieval manuscript data across diverse repositories, including textual content, physical characteristics, historical aspects, and artistic features, across diverse repositories.
• Simplify the citation complexities associated with medieval manuscripts by providing a unified data model that enables intuitive access and scholarly analysis.
• Enhance digital archiving practices to improve the organization, retrieval, and preservation of manuscript data, facilitating efficient management and accessibility in digital libraries.
• Support scholarly research by enabling complex queries that connect textual content with historical contexts, allowing scholars to trace the provenance, influence, and evolution of medieval texts.
• Enhance interoperability and usability of manuscript data in the digital humanities by standardizing data representation and ensuring seamless integration across repositories.
• Foster interdisciplinary collaboration by promoting holistic understanding through facilitating connections among disciplines such as history, literature, and art.

The Graffoo diagram illustrates the classes and properties introduced in MMDIO.

The current version of MMDIO framework reuses several ontologies to create a comprehensive information structure, each serving a specific function within the system:

• FaBiO, the FRBR-aligned Bibliographic Ontology, is crucial for describing bibliographic records and their various manifestations, underpinning the framework's approach to metadata handling.


• FOAF (Friend of a Friend) is employed to describe people, linking their profiles, activities, and relations to documents and other entities, enhancing network and relationship mapping.


• FRBR core, an RDF vocabulary, is integrated to adopt its robust bibliographic framework, which is based on the Functional Requirements for Bibliographic Records, facilitating complex bibliographic data representation.


• ARCO core is fundamental to our framework's structure, providing a comprehensive set of classes and properties that define the core concepts and relations within the cultural heritage domain. It forms the backbone for managing and relating complex heritage information.


• ARCO location is utilized for detailed geographic and spatial data representation. It allows for the precise mapping and characterization of locations related to cultural heritage items, facilitating advanced spatial queries and analysis.


• C4O (Citation Counting and Context Characterization Ontology) supports the detailed characterization of citation contexts and counting, enriching the bibliometric capabilities of our framework.


• DoCO (Document Components Ontology), used for the fine-grained description of document structures, enables detailed parsing and annotation of document components.


• DEO (Discourse Elements Ontology) provides a vocabulary for tagging and relating different rhetorical elements within texts, which is vital for discourse analysis.


• BiRO (Bibliographic Reference Ontology) complements FaBiO by focusing on the referencing process, ensuring comprehensive documentation of bibliographic references and citations.


• DCTerms, a broad metadata specification, is utilized for its well-established set of properties and classes, supporting standardized metadata representation across various content types.


• CITO (Citation Typing Ontology), like C4O, enhances our framework by allowing detailed characterization of citation types and natures, factually and rhetorically.


• LITERAL, an ontology pattern, is adapted to model literals as individuals in RDF, enabling their use as subjects or objects in RDF statements, thus providing flexibility in data representation.


• RDF and RDFS (RDF Schema) form the backbone of our framework, offering foundational elements for describing resources and structuring metadata.


• TI is a time interval ontology is utilized to describe specific periods marked by start and end dates, crucial for historical data representation and temporal querying.


• TVC (Temporal Value Contexts), another ontology pattern, is used for describing situations where entities hold values within specific times and contexts, useful for dynamic data scenarios.


• XSD (XML Schema Definition), is used for defining detailed data types and structures, ensuring data integrity and validation across the framework.

The subsequent sections will provide an overview of all entities defined, showcase examples of usage, and describe some queries that our framework can answer, demonstrating its utility and versatility in handling complex semantic data.

Application of ontology

To ensure seamless integration of data from various platforms, a standardized classification approach is employed. Specifically, all data is meticulously organized according to the FaBiO framework. This involves categorizing entities at the Expression level for their intellectual and thematic content, and at the Manifestation level for their physical embodiments. FaBiO, standing for FRBR-aligned Bibliographic Ontology, serves as the foundation for classifying entities within the MMDIO Ontology. FaBiO reinterprets the FRBR framework, aligning its entities more closely with users' perspectives. It distinguishes between the intellectual content of works (Expressions) and their physical embodiments (Manifestations), thus bridging the gap between FRBR's conceptual model and practical user needs.

Conversely, Manifestation in FaBiO refers to the physical embodiment of an Expression, which is crucial for understanding publishing, preservation, and accessibility. Entities like codices, folios, and bindings, capturing the tangible form of works, are classified under the fabio:Menifestation category within the MMDIO Ontology.

Integration of Ontology Classes and Properties Across Use Cases

In addition to textual content, the use cases also address the physical characteristics, artistic features of manuscripts as well as geographical and chronological information. Physical attributes like foliation, binding, and decorative elements provide essential contextual information about the materiality and production of manuscripts. These physical characteristics, along with textual metadata, contribute to the comprehensive cataloging and organization of manuscript resources within the Digital Resource Collection. The use cases underscore the multidimensional nature of manuscript studies within the digital library framework, highlighting the interconnectedness of physical characteristics, textual information, and artistic elements in facilitating scholarly research and exploration.

Shared Elements between use case 1 and 2

The shared elements between use cases 1 and 2 highlight key features of the data model used to represent medieval manuscripts and their related collections. These elements allow for a comprehensive understanding and exploration of the data.

The mmdio:DigitalResourceCollection class serves as the repository for the entire collection, integrating data from diverse collections and providing information about the type of associated collection and organization using the entity (foaf:Organization). The entities containing information about medieval manuscripts are part of this collection.

The mmdio:ManuscriptCollection class, with properties like frbr:part, frbr:partOf, and frbr:embodiment, facilitates the aggregation and physical manifestation of manuscript data, enhancing navigation and study of related documents. By using properties like tvc:atTime and aro:hasLocation, it represents the spatial and temporal information of these collections.

The memo:Manuscript class, incorporating properties such as frbr:part and memo:hasTextualMetadata, includes textual content and glosses considered integral parts of the manuscript. Both memo:Text and memo:Gloss classes are embodied within the memo:Folio. The glosses provide valuable commentary on the manuscript's text and are cited as references supporting its content. The memo:Gloss class, an rdf:subClassOf of fabio:Comment, presents annotations related to a specific work, enhancing understanding. The memo:Manuscript class, linked to the property arco:hasLocation, provides geographical information associated with the manuscript. It offers comprehensive textual information, including incipits (opening words or passages) and explicits (closing words or passages). These elements are crucial in manuscript studies as incipits help identify the beginning of specific texts, while explicits signify their end.

The biro:BibliographicList class, with properties like biro:references and cito:cites, is integral to the scholarly utility of this collection. It provides a structured assemblage of references intricately citing the manuscript collection. The list forms a detailed bibliographic network that connects various references using the biro:BibliographicReference class, offering rich scholarly context and enhancing the research value of the collection.

The memo:Codex class, with properties such as dcterms:identifier, mmdio:hasFoliation, memo:hasDecoration, and frbr:part, provides information about the physical aspects such as foliation and decorative elements crucial for cataloging. It contains folios representing the leaves or pages of the manuscript and includes binding to capture the physical characteristics and structure of the manuscript, tying everything together into a complete codex book. The memo:Folio class, with properties like frbr:part, deconstructs into sides, with the recto (front page of folio) and verso (back side of folio) denoted as memo:Recto and memo:Verso. Unique identifiers, like a sequence number or description, are assigned to each side, reflecting their order and content in the manuscript. The memo:Binding class, with properties such as dcterms:extent, memo:SizeMeasurement, memo:hasLength, and memo:hasWidth, physically captures the binding aspect of the codex, quantifying binding dimensions and measurements, and specifying units like millimeters, centimeters, decimeters, or meters.

Use Case 1: Enhanced Cataloging and Access in Digital Library of Mosaico

Challenges: Address the fragmented and disorganized presentation of manuscripts which hinders efficient academic research.

Strategy: Reclassify the "Authenticum" collection authored by the Christina Vano in 2010, ensuring that each manuscript and book is detailed at appropriate FRBR levels (Expression and Manifestation).

The unique aspects of this use case include:

Expected Outcome: Streamlined navigation and improved accessibility to manuscript collections, leading to better research outcomes and user engagement.

Use Case 2: Enhancing Scholarly Access to Medieval Manuscripts via the Irnerio Platform

Challenges: The current layout and organizational structure of the Irnerio platform hinder efficient access to and analysis of manuscript data.

Strategy: Overhaul the data presentation and classification system to improve the structure and navigability of the platform.

key aspects of this Usecase.

Expected Outcome: A more navigable, user-friendly platform that enhances scholarly research and facilitates access to detailed manuscript data..

Use Case 3: Cross-Platform Integration for a Unified Research Framework:

Challenges: A more navigable, user-friendly platform that enhances scholarly research and facilitates access to detailed manuscript data.

Strategy: Create a unified data model that connects and integrates data from the Mosaico and Irnerio platforms.

The fabio:Book (using cito:cites) helps link the Mosaico and Irnerio platforms by establishing a citation relationship between a book in Mosaico and a manuscript present in Irnerio. This relationship allows for seamless sharing and linking of manuscript data, enabling researchers to navigate between both platforms efficiently.

Expected Outcome: A cohesive and comprehensive framework that supports broader and more detailed scholarly research across platforms.

Use Case 4: Streamlining Montecassino, Olomouc, Arbores, Roffredo Beneventano, and Satana Collections in the Mosaico Digital Library

Challenges: Digital editions of several collections within the Mosaico digital library, specifically Montecassino, Olomouc, Arbores, Roffredo Beneventano, and Satana, present unique structural and bibliographic features that require additional semantic modeling beyond what was covered in Use Case 1.

Strategy: Enhance the ontology to accurately capture these distinctive elements and ensure consistent, navigable, and semantically rich representations of each collection.

The Montecassino edition by Martin Bartram includes the signature of the original author Goffredus Tranensi, which is modeled using the new object property mmdio:hasSignature that links a fabio:Book to a foaf:Person. This person is also referenced in bibliographic citations, modeled through the cito:isCitedBy property linking foaf:Person with biro:bibliographicReference. In Montecassino, sections are further divided into subsections, represented using the doco:contains property to link a doco:Section with a mmdio:SubSection. Subsections carry descriptive metadata through the use of dcterms:title and core:description. Furthermore, for the Montecassino, Olomouc, and Roffredo Beneventano collections, the ontology has been extended to connect sections, subsections, and manuscripts directly to folios. This is achieved using the newly introduced object property mmdio:refersToManifestation, which links doco:Section, mmdio:SubSection, and memo:Manuscript entities with memo:Folio. This connection facilitates direct navigation and scholarly reference to specific folios within each collection.

Expected Outcome: A more detailed, structured, and user friendly representation of complex manuscript editions within Mosaico, improving scholarly access and ensuring consistency in handling diverse digital collections.

Competency Questions and SPARQL Queries

PREFIX mmdio: <https://w3id.org/irnerio-mosaico/ontology/mmdio/>
PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX owl: <http://www.w3.org/2002/07/owl#>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>
PREFIX frbr: <http://purl.org/vocab/frbr/core#>
PREFIX memo: <https://w3id.org/irnerio/ontology/memo>
PREFIX dcterms: <http://purl.org/dc/terms/>
PREFIX fabio: <http://purl.org/spar/fabio/>
PREFIX biro: <http://purl.org/spar/biro/>
PREFIX c4o: <http://purl.org/spar/c4o/>
PREFIX foaf: <http://xmlns.com/foaf/0.1/>
PREFIX arco: <https://w3id.org/arco/ontology/location/>
PREFIX doco: <http://purl.org/spar/doco/>
PREFIX deo: <http://purl.org/spar/deo/>
PREFIX core: <https://w3id.org/arco/ontology/core/>
PREFIX cito: <http://purl.org/spar/cito/>
PREFIX ti: <http://www.ontologydesignpatterns.org/ont/owl/timeinterval.owl#>
PREFIX tvc: <http://purl.org/spar/tvc/>
PREFIX literal: <http://www.essepuntato.it/2010/06/literalreification/>
        

What manuscript collections are cited in the book titled "Authenticum"?

SELECT ?manuscriptCollection ?collectionTitle
WHERE {
  ?book a fabio:Book ;
        dcterms:title "Authenticum" .
  ?book cito:cites ?manuscriptCollection .
  ?manuscriptCollection a mmdio:ManuscriptCollection ;
                   dcterms:title ?collectionTitle .
}
        

Retrieve all the folios that contain a gloss including gloss title, identifier, type and placement in the text?

SELECT ?folio ?glossTitle ?glossIdentifier ?glossType ?glossPlacement
WHERE {
  
  ?gloss a memo:Gloss ;
         dcterms:title ?glossTitle;
         dcterms:identifier ?glossIdentifier;
         mmdio:hasGlossType ?glossType;
         mmdio:hasGlossPlacement ?glossPlacement;
         frbr:embodiment ?folio .
  ?folio a memo:Folio .
  
  FILTER(?glossType IN (mmdio:ordinary, mmdio:extravagant))
 FILTER(?glossPlacement IN (mmdio:interlinear, mmdio:marginal))
}
        

Retrieve all manuscripts from the `El Escorial, S.I.9' collection along with the bibliographic references and the book that cites this collection.

SELECT  ?manuscript ?manuscriptTitle ?references ?bookTitle 
WHERE {
  ?book a fabio:Book ;
        dcterms:title ?bookTitle ;
        cito:cites ?collection .  
?collection a mmdio:ManuscriptCollection ;
     dcterms:title "El Escorial, S.I.9" ;
              frbr:part ?manuscript .
  ?manuscript a memo:Manuscript ;
               dcterms:title ?manuscriptTitle .
  ?bibliograhicList a biro:BibliographicList ;
        cito:cites ?collection .
  ?bibliograhicList biro:references ?bibliographicReference .
  ?bibliographicReference a biro:BibliographicReference ;
                          c4o:hasContent ?references .

}


        

Retrieve bibliographic references that cite books, including the titles and authors of the cited books.

SELECT  ?references ?bookTitle  ?authorName
WHERE { 
  ?bibliographicReference a biro:BibliographicReference ;
                            cito:cites ?book;
                          c4o:hasContent ?references .
    ?book a fabio:Book ;
        dcterms:title ?bookTitle ;
        dcterms:creator ?person .
  ?person a foaf:Person ;
          foaf:name ?authorName .

}

        

Retrieve all manuscripts that include incipit, explicit, follows, and `notes' annotations.

SELECT ?Manuscript ?title ?TextualMetadata ?hasTextualContent ?TextualRole
WHERE {
  ?Manuscript a memo:Manuscript ;
              dcterms:title ?title ;
              memo:hasTextualMetadata ?TextualMetadata .
  ?TextualMetadata a mmdio:TextualMetadata ;
                   memo:withTextualRole ?TextualRole ;
                   mmdio:hasTextualContent ?hasTextualContent .
  FILTER(?TextualRole IN (memo:incipit, memo:explicit, mmdio:follows, mmdio:notes))
}



        

List all folios within the codex `http://irnerio.cirsfid.unibo.it/codex/006/', including the identifiers for each recto and verso side.

SELECT ?Folio ?RectoIdentifier ?VersoIdentifier
WHERE {
  ?codex a memo:Codex ;
         dcterms:identifier "http://irnerio.cirsfid.unibo.it/codex/006/" ;
         frbr:part ?Folio .
  ?Folio a memo:Folio .
    OPTIONAL {
    ?Folio frbr:part ?recto .
    ?recto a memo:Recto ;
           dcterms:identifier ?RectoIdentifier .
  }
  
  OPTIONAL {
    ?Folio frbr:part ?verso .
    ?verso a memo:Verso ;
           dcterms:identifier ?VersoIdentifier .
  }

}

        

Retrieve the critical edition and critical edition volume that cite the `Moralia sive Expositio in Iob' manuscript.

   SELECT ?CriticalEdition ?editionTitle ?CriticalEditionVolume ?volumeIdentifier
WHERE {
  # Find critical edition volumes that cite the manuscript
  ?CriticalEditionVolume a memo:CriticalEditionVolume ;
                         dcterms:identifier ?volumeIdentifier ;
                         cito:cites ?manuscript .
  ?manuscript a memo:Manuscript ;
              dcterms:title "De inventione librorum Moralium S. Gregorii" .
  ?CriticalEdition a fabio:CriticalEdition ;
                   dcterms:title ?editionTitle ;
                   frbr:realization ?CriticalEditionVolume .
}



        

Retrieve the decoration details, such as initials for each codex.

 SELECT ?codexIdentifier ?initial

WHERE {
    ?codex a memo:Codex ;
           dcterms:identifier ?codexIdentifier;
         mmdio:hasDecoration ?decoration.
    
    ?decoration a mmdio:Decoration;
            mmdio:hasInitial ?initial.
                          
}

        

Retrieve the dimensions of the binding (length and width) and the size measurement unit for the codex 'http://irnerio.cirsfid.unibo.it/codex/006/'.

SELECT ?binding ?length ?width ?unit 
WHERE {

  ?codex a memo:Codex ;
         dcterms:identifier "http://irnerio.cirsfid.unibo.it/codex/006" ;
         frbr:part ?binding .
  ?binding a memo:Binding ;
           dcterms:extent ?sizeMeasurement .
  ?sizeMeasurement a memo:SizeMeasurement ;
                   memo:hasLength ?length ;
                   memo:hasWidth ?width ;
                   memo:hasSizeMeasurementUnit ?unit .
  FILTER(?unit IN (memo:millimeters, memo:centimeters, memo:decimeters, memo:meters))
}
        

Retrieve the titles and time intervals (start and end dates) of `Paris, Mazar. 45’ manuscript collection.

SELECT ?startDate ?endDate 

{
  ?manuscriptCollection a mmdio:ManuscriptCollection ;
                         dcterms:title "Paris, Mazar. 452" ;
                        tvc:atTime ?timeInterval .
  ?timeInterval a ti:TimeInterval ;
                ti:hasIntervalStartDate ?startDate ;
                ti:hasIntervalEndDate ?endDate .
}
        

Retrieve current physical locations of all manuscripts?

SELECT  ?locationName
WHERE {
  ?manuscript a memo:Manuscript ;
              core:hasLocation ?location .
  ?location a dcterms:Location ;
            arco:hasLocationType arco:CurrentPhysicalLocation ;
            mmdio:hasLocationName ?locationName .
}

        

Retrieve all the folios and identifiers of the manuscript titled 'Tabula materiae'?

 

SELECT ?Folio ?RectoIdentifier ?VersoIdentifier
WHERE {
 
  ?manuscript a memo:Manuscript ;
              dcterms:title "Tabula materiae" ;
              frbr:part ?text .
  ?text a memo:Text ;
        frbr:embodiment ?Folio .

  ?Folio a memo:Folio .
  OPTIONAL {
    ?Folio frbr:part ?recto .
    ?recto a memo:Recto ;
           dcterms:identifier ?RectoIdentifier .
  }
  OPTIONAL {
    ?Folio frbr:part ?verso .
    ?verso a memo:Verso ;
           dcterms:identifier ?VersoIdentifier .
  }
}
    
  

 

SELECT ?TextualRole ?hasTextualContent 
WHERE {
  ?Manuscript a memo:Manuscript ;
              dcterms:title "Tres libri cum glossa Accursii" ;
              memo:hasTextualMetadata ?TextualMetadata .
  ?TextualMetadata a mmdio:TextualMetadata ;
                   memo:withTextualRole ?TextualRole ;
                   mmdio:hasTextualContent ?hasTextualContent .
  
}
    
  

 
SELECT ?digitalResourceCollection ?title ?creatorName
WHERE {
  ?digitalResourceCollection a mmdio:DigitalResourceCollection ;
                             dcterms:title ?title ;
                             dcterms:creator ?creator .
  ?creator a foaf:Organization ;
           foaf:name ?creatorName .
}
    
  

 

  SELECT  ?book  ?bookTitle  ?manuscript ?manuscriptTitle
WHERE {
  ?book a fabio:Book ;
        frbr:partOf  ?bookCollection;
        dcterms:title ?bookTitle;
        cito:cites ?manuscript .
   ?bookCollection a mmdio:DigitalResourceCollection;
           dcterms:title "mosaico" .
    ?manuscript a memo:Manuscript ;
              dcterms:title ?manuscriptTitle ;
             frbr:partOf   ?manuscriptCollection.
   ?manuscriptCollection a mmdio:DigitalResourceCollection;
           dcterms:title "irnerio" .
}